合约结构介绍

1.SPDX 版权声明

bytecode metadata 介绍

2.pragma solidity 版本限制

3.contract 关键字

4.import 导入声明

5.interface: 接口

6.library:库合约

---

合约结构介绍

1.SPDX 版权声明

第 1 行 // SPDX-License-Identifier: MIT 就是合约的版权声明。其中 SPDX-License-Identifier(SPDX 许可标示) 是标注当前的智能合约采用什么样的对外开放标准该标准规定了别人是否拥有商业开发学习使用等权利。代码中使用的 MIT 规定了其他人随便用该代码但出问题不负责。MIT 详细解释SPDX 许可标示的注释在文件的任何位置都可以被编译器识别到的按照规范建议把它放在文件的顶部第一行。

如果一个项目开源了智能合约的源代码可以更好地建立社区信任。但是由于提供源代码就不可避免的涉及到版权或者法律问题。所以 solidity 鼓励开源但是开源并不等于放弃版权。如果你不想指定任何许可证或者代码就是不想开源Solidity 推荐使用 UNLICENSED ;UNLICENSED 不存在于 SPDX 许可证列表中,与 UNLICENSE 授予所有人所有权利不同它比 UNLICENSE 多一个 D 字母。

需要注意: 源代码这里编译器不会验证 SPDX 许可标示是否符合规范比如我可以写为 // SPDX-License-Identifier: ANBANG 并不会影响代码的运行。但是这里的标示会被打包在 bytecode metadata 里。

bytecode metadata 介绍

当我们使用 remix 编译合约的时候会在根目录创建 artifacts 文件夹其中包含 build-info 记录构建信息的文件夹以及每个合约名字作为文件名的文件夹比如 contract Hello 将生成

• Hello.json 文件

• Hello_metadata.json 文件

Hello.json 文件结构

{
  deploy: {},
  data: {
    bytecode: {},
    deployedBytecode: {},
    gasEstimates: {},
    methodIdentifiers: {},
  },
  abi: [],
};

Hello_metadata.json 文件结构

{
  compiler: {
    version: "0.8.17+commit.xxx",
  },
  language: "Solidity",
  output: {
    abi: [],
    devdoc: {},
    userdoc: {},
  },
  settings: {},
  sources: {
    "aaa.sol": {
      keccak256:
        "0x637c141739144cd991b9350336a1f8c3b948811d7ed743fefb4aad99d7bb362f",
      license: "kyp",
      urls: [
        "bzz-raw://9eea517225b90242d6e3761046f5f5a8f0a2393747c89f3af01f34ad00764dc4",
        "dweb:/ipfs/QmXp5wap9ZNC9fihdA7aLMe7bKWBjeAuv7khEuvKrgp9Bx",
      ],
    },
  },
  version: 1,
};

// SPDX-License-Identifier: kyp 中的 kyp 就是在 sources -> filename.sol -> license 中

2.pragma solidity 版本限制

第 2 行 pragma solidity ^0.8.17; 指令它是告诉编译器我当前的合约代码采用的是 Solidity 0.8.17 这个版本为基础编写的解析部署时需要在匹配的版本下进行在区块链浏览器上进行合约验证时也需要选择匹配的版本。

⓵ 使用 ^ 的意义和优点

而 ^0.8.17 中的 ^ 表示小版本兼容大版本不兼容相当于 pragma solidity >= 0.8.17 < 0.9.0;。他既不允许低于0.8.17的编译器编译也不允许大于等于 0.9.0 版本的编译器进行编译。之所以这么写不写死 pragma solidity 0.8.17; 是为了可以享受到编译器的补丁版比如以后出来了 0.8.40 版本那么当前合约是可以运行在未来的 0.8.40 这个新版本的编译器。但是如果是大版本升级到了 0.9.0那么编译器不会用新版的0.9.x解析会使用 0.8 的最后一个稳定版本来进行解析编译。这里如果不加 ^,直接写pragma solidity 0.8.17;,就是告诉编译器当前合约只选择在 0.8.17 版本来编译和部署这样做的缺点就是享受不到以后出的补丁版的编译器。

⓶ 跨大版本的合约

如果你打算跨大版本的合约可以使用> />=/</<=来操作比如 pragma solidity >=0.7.0 <0.9.0;。

注意pragma 指令只对当前的源文件起作用如果把文件 B 导入到文件 A文件 B 的 pragma 将不会自动应用于文件 A。

• 总结:

  1. pragma solidity ^0.8.17; 是用来告诉编译器应该选择什么版本来解析编译当前代码。

  2. pragma 指令只对当前的源文件起作用。

注一份源文件可以包含多个版本声明、多个导入声明和多个合约声明。

3.contract 关键字

第 3 行的 contract Hello {} 是合约的基本结构其中 contract 声明了当前代码块内是一个完整的合约。而 Hello 是当前合约的名字合约名称是必须的首字母一般采用大写字母开头。

contract 代表特殊的意义这种有特殊意义的词在编程界里一般被称为 保留关键字保留关键字是现在或者将来被用到的特殊代指都有固定意义所以保留关键字不能作为变量名和函数名字。

• 总结:

  1. contract 基本结构是 contract ContractName {}

  2. Solidity 合约中合约的名字是必须的。

  3. 合约的名称一般约定为 大驼峰命名方式

  4. contract 是保留关键字

  5. 保留关键字不能作为变量名和函数名

• 扩展:

  1. 合约的编写规范参照 合约编码规范

  2. 更多保留关键字参照 变量名命名规则 详细阅读。

注一份源文件可以包含多个版本声明、多个导入声明和多个合约声明。

⓵ 变量

合约内的 message 叫做状态变量状态变量是永久地存储在合约存储中的值。关于变量的更多信息会在后续 [变量] 那一章详细介绍

⓶ 函数

函数是代码的可执行单元是一组逻辑的集合。关于变量的更多信息会在后续 函数 那一章详细介绍

⓷ this 关键字

Solidity 中 this 代表合约对象本身

• 可以通过 address(this) 获取合约地址。

• 可以通过 this.fnName 获取 external 函数

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;
​
contract Demo {
    function contractAds() external view returns (address) {
        return address(this);
    }
​
    function testExternal() external view returns (address) {
        return this.contractAds();
    }
}

⓸ 合约地址/合约创建者地/合约调用者地址

这三个地址概念一定要完全理解。

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;
​
// 这三个地址的概念一定要理解清楚
contract Demo {
    address public owner;
​
    constructor() {
        // 可以用在 constructor 内获取当前合约地址
        owner = address(this);
​
        // 不可以在构造函数内调用函数因为此时合约还没有完成构建好。
        // this.caller(); 相当于从外部调用 caller 方法
        // owner = this.caller();
    }
​
    function caller() external view returns (address) {
        return this.contractAds(); // 内部调用 external 可见性的函数
    }
​
    function contractAds() external view returns (address) {
        return address(this);
    }
}

⓹ 合约属性:type 关键字

• type(C).name:获得合约名

• type(C).creationCode:获得包含创建合约字节码的内存字节数组。它可以在内联汇编中构建自定义创建例程尤其是使用 create2 操作码。 不能在合约本身或派生的合约访问此属性。 因为会引起循环引用。

• type(C).runtimeCode:获得合约的运行时字节码的内存字节数组。这是通常由 C 的构造函数部署的代码。 如果 C 有一个使用内联汇编的构造函数那么可能与实际部署的字节码不同。 还要注意库在部署时修改其运行时字节码以防范定期调用guard against regular calls。 与 .creationCode 有相同的限制不能在合约本身或派生的合约访问此属性。 因为会引起循环引用。

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;
​
contract Hello {
    string public message = "Hello World!";
}
​
contract Demo {
    function name() external pure returns (string memory) {
        return type(Hello).name;
    }
​
    function creationCode() external pure returns (bytes memory) {
        return type(Hello).creationCode;
    }
    function runtimeCode() external pure returns (bytes memory) {
        return type(Hello).runtimeCode;
    }
}

除了上面介绍的版权声明版本限制contract 外合约文件还包括 import, interface,library一起展开介绍下

4.import 导入声明

功能从其他文件内倒入需要的变量或者函数。

⓵ 导入方式

既可以导入本地文件也可以导入 url(网络上的 ipfshttp 或者 git 文件)

1. 导入所有的全局标志

   import "filename";

   到当前全局范围

   1. 导入本地文件:import "./ERC20.sol";其中./表示当前目录查找路径参考

   2. 导入网络文件:import "https://github.com/aaa/.../tools.sol";

   3. 导入本地 NPM 库:

      1. $ npm install @openzeppelin/contracts

      2. import "@openzeppelin/contracts/token/ERC721/ERC721.sol";

2. 导入所有的全局标志并创建新的全局符号

   1. 方式一: import * as symbolName from "filename";

   2. 方式二: import "filename" as symbolName;

3. 按需导入按需修改名称

   1. import {symbol1 as aliasName, symbol2} from "filename";

不推荐导入变量标示名到当前全局范围的方式因为不可控容易污染当前的命名空间。如果全局导入推荐使用 import "filename" as symbolName;

注一份源文件可以包含多个版本声明、多个导入声明和多个合约声明。

⓶ 导入时候的本地路径

上文中的 filename 总是会按路径来处理以 / 作为目录分割符、以 . 标示当前目录、以 .. 表示父目录。 当 . 或 .. 后面跟随的字符是 / 时它们才能被当做当前目录或父目录。 只有路径以当前目录 . 或父目录 .. 开头时才能被视为相对路径。

用 import "./x.sol" as x; 语句导入当前源文件同目录下的文件 x.sol 。 如果用import "x.sol" as x; 代替可能会引入不同的文件在全局 include directory 中。

最终导入哪个文件取决于编译器见下文到底是怎样解析路径的。 通常目录层次不必严格映射到本地文件系统 它也可以映射到能通过诸如 ipfshttp 或者 git 发现的资源。

5.interface: 接口

⓵ 接口使用案例

在下面的例子中定义了 cat 合约以及 dog 合约。他们都有 eat 方法.以此他们都可以被上面的 animalEat 接口所接收。

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;
​
contract Cat {
    uint256 public age;
​
    function eat() public returns (string memory) {
        age++;
        return "cat eat fish";
    }
​
    function sleep1() public pure returns (string memory) {
        return "sleep1";
    }
}
​
contract Dog {
    uint256 public age;
​
    function eat() public returns (string memory) {
        age += 2;
        return "dog miss you";
    }
​
    function sleep2() public pure returns (string memory) {
        return "sleep2";
    }
}
​
interface AnimalEat {
    function eat() external returns (string memory);
}
​
contract Animal {
    function test(address _addr) external returns (string memory) {
        AnimalEat general = AnimalEat(_addr);
        return general.eat();
    }
}

⓶ type(I).interfaceId

返回接口I 的 bytes4 类型的接口 ID接口 ID 参考 EIP-165 定义的 接口 ID 被定义为 XOR 异或 接口内所有的函数的函数选择器除继承的函数。

上面的代码种可以增加如下的函数来查看 interfaceId;

contract Animal {
    // ...
    function interfaceId() external pure returns (bytes4) {
        return type(AnimalEat).interfaceId;
    }
}

更多内容在interface:接口那一章详细介绍。

6.library:库合约

库与合约类似但它的目的是在一个指定的地址且仅部署一次然后通过 EVM 的特性来复用代码。

library Set {
    struct Data { mapping(uint => bool) flags; }
    function test(){
    }
}

其他合约调用库文件的内容直接通过库文件名.方法名例如Set.test()。